#version 330 core

uniform sampler2D diffuse;
uniform sampler2D specular;
uniform sampler2D bumpmap;

in vec2 pos_zw;
in vec3 ec_pos;
in vec2 uv;

layout (location = 0) out vec4 diffuse_specular;
layout (location = 1) out vec4 normal_depth;

#include <gbuffer_include.frag>
#include <tangentspace_include.frag>

void main()
{
	vec4 diff = texture(diffuse, uv);
	if ( diff.a < 0.1 ) discard;

	vec3 t, b;
	per_fragment_tangent_space(ec_pos, uv, t, b);
	vec3 normal = normalize( cross(dFdx(ec_pos), dFdy(ec_pos)) );

	vec3 bump = normalize(texture2D(bumpmap, uv).xyz*2.0 - vec3(1.0));

	mat3 mr = mat3(t, b, normalize(normal));
	vec3 n = mr * bump;

	diffuse_specular.rgb = diff.rgb;
	diffuse_specular.a = texture(specular, uv).r;

	float front = gl_FrontFacing ? 1.0 : -1.0;
	normal_depth.xyz = normalize(n*front);
	normal_depth.w = pos_zw.x/pos_zw.y;
}
