BÖSER WATZ
(by Cylex & Telespielator 3/2018)

Bist Du bereit für den ultimativen Fressflash? Dann setz' Dich
vor Deinen Schneider CPC 464 und ab geht die wilde Jagd!
Du bist der Böse Watz in diesem actiongeladenen Arcadekracher
und musst dreizehn Kinder fressen, bevor dreizehn Kinder entfliehen
können. Doch sei auf der Hut, die kleinen Biester rennen schneller
als Du und zu allem Überfluss versucht DJ Cylex, Dich mit seinem
Psycho-Watzcore zu verwirren! Dieses brandneue Superspiel wurde
geschrieben in zehn eng gepackten Zeilen reinem Locomotive-BASIC
exklusiv für den Schneider CPC 464 und wird Dich viele Nächte vor
den Bildschirm fesseln. Doch vergiss nicht: Es ist nur ein Spiel
und Kinder fressen wird im Real Life mit Haftstrafen nicht unter
zehn Jahren bestraft! Dieses Spiel ist nicht für Personen unter
18 Jahren geeignet! Spielen auf eigene Gefahr, keine Haftung für
Schäden an Seele oder Joystick!

Programmcode:

10 MODE 0:x=10:y=12:a=1:b=1:IF p=13 THEN CLS:?"Boeser Watz gewinnt!":END
20 LOCATE x,y:? CHR$(225):s=INT(RND(1)*1000)+1:SOUND 1,s
30 IF JOY(0)=4 THEN LOCATE x,y:CALL &BD19:? CHR$(32):IF x>1 THEN x=x-1
40 IF JOY(0)=8 THEN LOCATE x,y:CALL &BD19:? CHR$(32):IF x<20 THEN x=x+1
50 IF JOY(0)=1 THEN LOCATE x,y:CALL &BD19:? CHR$(32):IF y>1 THEN Y=Y-1
60 IF JOY(0)=2 THEN LOCATE x,y:CALL &BD19:? CHR$(32):IF Y<24 THEN y=y+1
70 IF b=x AND a=y THEN LOCATE x,y:? CHR$(224):p=p+1:FOR w=1 TO 99:NEXT w:GOTO 10
80 LOCATE b,a:? CHR$(32):b=b+1: IF b=21 THEN c=c+1:b=1:a=INT(RND(1)*24)+1
90 LOCATE b,a:? CHR$(249):IF c=13 THEN GOTO 100 ELSE GOTO 20
100 PRINT"Boeser Watz verliert":? "Watz:"p" Kinder:"c:SOUND 1,400,300:END

Empfohlener Emulator: WinAPE (http://www.winape.net/) mit Einstellung CPC464

Programm nach dem Eingeben starten mit RUN.

Programmerklärung:

Zeile 10: Schaltet in den Mode 0 (20x25), definiert Variablen (x & y für die Position des Watz, a & b für die Position des Kindes), fragt ab, ob der Böse WATZ gewonnen hat.
Zeile 20: Zeichnet den grimmigen Bösen Watz (am Anfang jeder Runde in die Bildschirmmitte, spielt einen Watzcore-Ton.
Zeilen 30-60: Abfrage des Joysticks und entsprechende Veränderung der Variablen x & Y für die Bildschirmposition des Bösen Watz mit Abfrage, ob ein Bildschirmrand erreicht ist. Der CALL-Befehl vermindert das Flackern.
Zeile 70: Wenn der Watz ein Kind erwischt hat, grinst er kurz, dann geht es weiter in Zeile 10
Zeilen 80 & 90: Das Kind läuft zufallsbasiert von links nach rechts über den Bildschirm. Erreicht es den rechten Bildschirmrand, bekommen die Kinder (Variable c) einen Punkt. Haben die Kinder 13 Punkte, verliert der Watz (Zeile 100), sonst geht es von vorne los.
Zeile 100: Wenn der böse Watz verliert, wird der Punktestand angezeigt.

Kontakt: telespielator@gmx.de