                             org 4082h          
4082 55..                    defs 7fh, $55        ; filler to offset origin, untouched by code
               bitmap:                            ; prefix the code with inverted bitmap data
4101 fdaecf8df6fb6db6        defb $fd,$ae,$cf,$8d,$f6,$fb,$6d,$b6
               start:                             ; start = $4109 => BC
4109 5a                      ld e, d              ; STKEND = $44xx => DE, copy $44 => E
               col:                    
410a 0609                    ld b, 9              ; start each col on the 10th row, immediately
               rotate:                            ; plot an asterisk and its 4 rotations
410c c5                      push bc              ; save BC as it gets destroyed 
410d cdf508                  call 08f5h           ; point HL at (col C, row B)
4110 c1                      pop bc               ; retrieve BC
4111 3617                    ld (hl),23           ; plot one *
4113 3e12                    ld a, 18             ; load A with rotation constant
4115 90                      sub b                ; A = 18-B
4116 c8                      ret z                ; If col = 0 then exit before plotting bitmap
4117 41                      ld b, c              ; B = C and
4118 4f                      ld c, a              ; C = 18-B => rotate 90º clockwise around (9,9)
4119 cb0b                    rrc e                ; 8-bit rotate E, exit loop every 4 rotations
               check:                 
411b 30ef                    jr nc, rotate        ; don't plot / exit loop every 4th time
               xloop:                 
411d 2641                    ld h, $41            ; bitmap resides at $4100 + col, load the $41
411f 69                      ld l,c               ; and the col from C
4120 cb3e                    srl (hl)             ; grab 1 bit from bitmap
4122 10f7                    djnz check           ; use this bit for next row, until we run out
4124 0d                      dec c                ; otherwise, move on to next col
4125 e9                      jp (hl)              ; print the next col and its rotations
               end:          
4126
