                             org 4082h          
4082 55..                    defs 7fh,55h         ; filler to offset origin, untouched by code
               bitmap:       		          ; prefix the code with the bitmap data
4101 fdaecf8df6fb6db6        defb fdh,aeh,cfh,8dh,f6h,fbh,6dh,b6h
               start:        		          ; start = $4109, comes loaded into BC
4109 59                      ld e,c               ; so col C = 9, save the 9 for later
               col:                   
410a 43                      ld b,e               ; start each col on the 9th row, and immediately
               rotate:       		          ; plot an asterisk and its rotations
410b c5                      push bc              ; save BC as it gets destroyed 
410c cdf508                  call 08f5h           ; point HL at (col C, row B)
410f c1                      pop bc               ; retrieve BC
4110 3e12                    ld a,18              ; load rotation constant
4112 be                      cp (hl)              ; use it to check if all 4 plots are done
4113 3808                    jr c, xloop          ; if all 4 plots already done, x-it the loop
4115 3617                    ld (hl),23           ; otherwise plot a *
4117 90                      sub b                ; A = 18-B
4118 41                      ld b,c               ; B = C and
4119 4f                      ld c,a               ; C = 18-B => rotate 90º clockwise
411a c8                      ret z                ; If col = 0 then exit before plotting bitmap
               check:                 
411b 30ee                    jr nc, rotate        ; if bit clear then plot it
               xloop:                 
411d 2641                    ld h,41h             ; bitmap resides at $4100 + col, load the $41
411f 69                      ld l,c               ; and the col from C
4120 cb3e                    srl (hl)             ; grab 1 bit from bitmap
4122 10f7                    djnz check           ; use this bit for next row, until we run out
4124 0d                      dec c                ; otherwise, move on to next col
4125 18e3                    jr col               ; print the next col and its rotations
               end:          
4127          
