org   16514   
        ds   127,$55	; filler to offset origin, untouched by code
bitmap:                 ; prefix the code with inverted bitmap data
        defb   $fd,$ae,$cf,$8d,$f6,$fb,$6d,$b6
start:			; start = $4109 => BC
        ld e, d		; STKEND = $44xx => DE, copy $44 => E
col:
        ld b, 9     	; start each col on the 10th row, immediately
rotate:			; plot an asterisk and its 4 rotations
        push bc     	; save BC as it gets destroyed 
        call $8f5   	; point HL at (col C, row B)
        pop bc      	; retrieve BC
        ld (hl), 23  	; plot one *
        ld a, 18     	; load A with rotation constant
        sub b       	; A = 18-B
        ret z	 	; If col = 0 then exit before plotting bitmap
        ld b,c      	; B = C and
        ld c,a      	; C = 18-B => rotate 90º clockwise around (9,9)
        rrc e		; 8-bit rotate E, exit loop every 4 rotations
check:
        jr nc, rotate  	; don't plot / exit loop every 4th time
xloop:
        ld h, $41	; bitmap resides at $4100 + col, load the $41
        ld l, c		; and the col from C
        srl (hl)    	; grab 1 bit from bitmap
        djnz check	; use this bit for next row, until we run out
        dec c       	; otherwise, move on to next col
        jp (hl)      	; print the next col and its rotations
end:
